// tb_mlkem_kg_katK_xsim.v - ML-KEM KeyGen vs NIST KAT, parametric K (KP) + CASE.
// xelab -generic_top KP=2|3|4 ; xsim -testplusarg CASE=n
//   KP=2 -> k2 vectors (ML-KEM-512), KP=3 -> k3 (768), KP=4 -> k4 (1024).
//   ek = 384*KP+32 bytes (==KAT pk), dk = 768*KP+96 bytes (==KAT sk).
`timescale 1ns/1ps
module tb_mlkem_kg_katK_xsim;
    parameter KP = 2;
    localparam EKB = 384*KP + 32;
    localparam DKB = 768*KP + 96;

    reg clk=0, rst_n=0, start_i=0;
    reg [2:0] k_i;
    reg [255:0] d_i, z_i;
    wire busy_o, done_o;
    reg [3:0] dbg_slot_i=0; reg [7:0] dbg_idx_i=0; wire [11:0] dbg_coeff_o;
    reg dbg_byte_sel_i=0; reg [10:0] dbg_byte_idx_i=0; wire [7:0] dbg_byte_o;
    reg [11:0] dbg_dk_idx_i=0; wire [7:0] dbg_dk_o;
    wire [255:0] dbg_rho_o, dbg_sigma_o;

    // KMAX defaults to 4 (worst-case sizing); KP selects the runtime k value.
    mlkem_top dut (
        .clk(clk), .rst_n(rst_n), .k_i(k_i), .d_i(d_i), .z_i(z_i), .start_i(start_i),
        .busy_o(busy_o), .done_o(done_o),
        .dbg_slot_i(dbg_slot_i), .dbg_idx_i(dbg_idx_i), .dbg_coeff_o(dbg_coeff_o),
        .dbg_byte_sel_i(dbg_byte_sel_i), .dbg_byte_idx_i(dbg_byte_idx_i), .dbg_byte_o(dbg_byte_o),
        .dbg_dk_idx_i(dbg_dk_idx_i), .dbg_dk_o(dbg_dk_o),
        .dbg_rho_o(dbg_rho_o), .dbg_sigma_o(dbg_sigma_o)
    );
    always #5 clk = ~clk;

    reg [255:0] dmem [0:0];
    reg [255:0] zmem [0:0];
    reg [7:0]   ek_gold [0:EKB-1];
    reg [7:0]   dk_gold [0:DKB-1];
    integer c, i, errors, casenum;
    reg [8*80-1:0] tag, dfile, zfile, ekfile, dkfile;

    initial begin
        if (!$value$plusargs("CASE=%d", casenum)) casenum = 0;
        $sformat(tag, "k%0d", KP);
        $sformat(dfile,  "sync_rtl/top/TB/vectors/kat_%0s_c%0d_d.hex",  tag, casenum);
        $sformat(zfile,  "sync_rtl/top/TB/vectors/kat_%0s_c%0d_z.hex",  tag, casenum);
        $sformat(ekfile, "sync_rtl/top/TB/vectors/kat_%0s_c%0d_ek.hex", tag, casenum);
        $sformat(dkfile, "sync_rtl/top/TB/vectors/kat_%0s_c%0d_dk.hex", tag, casenum);
        $readmemh(dfile,  dmem);
        $readmemh(zfile,  zmem);
        $readmemh(ekfile, ek_gold);
        $readmemh(dkfile, dk_gold);
        d_i = dmem[0]; z_i = zmem[0];
        k_i = KP[2:0];

        rst_n=0; repeat(4) @(posedge clk); rst_n=1; @(posedge clk);
        start_i=1; @(posedge clk); start_i=0;
        c=0; while(!done_o && c<2000000) begin @(posedge clk); c=c+1; end
        if(!done_o) begin $display("FAIL K=%0d case %0d: timeout", KP, casenum); $finish; end
        $display("=== ML-KEM K=%0d KAT case %0d: KeyGen done in %0d cyc ===", KP, casenum, c);

        errors = 0;
        dbg_byte_sel_i = 1'b0;
        for (i = 0; i < EKB; i = i + 1) begin
            dbg_byte_idx_i = i[10:0]; @(posedge clk); @(posedge clk);
            if (dbg_byte_o !== ek_gold[i]) begin
                if (errors < 8) $display("  EK[%0d] got=%02x exp=%02x", i, dbg_byte_o, ek_gold[i]);
                errors = errors + 1;
            end
        end
        for (i = 0; i < DKB; i = i + 1) begin
            dbg_dk_idx_i = i[11:0]; @(posedge clk); @(posedge clk);
            if (dbg_dk_o !== dk_gold[i]) begin
                if (errors < 8) $display("  DK[%0d] got=%02x exp=%02x", i, dbg_dk_o, dk_gold[i]);
                errors = errors + 1;
            end
        end
        if (errors == 0) $display("K=%0d CASE %0d PASS: ek (%0dB)==pk, dk (%0dB)==sk", KP, casenum, EKB, DKB);
        else             $display("K=%0d CASE %0d FAIL: %0d mismatches", KP, casenum, errors);
        $finish;
    end
    initial begin #120000000; $display("FAIL: global timeout"); $finish; end
endmodule